home *** CD-ROM | disk | FTP | other *** search
/ Amiga Collections: Taifun / Taifun 143 (1990-08-15)(Ossowski, Stefan)(DE)(PD).zip / Taifun 143 (1990-08-15)(Ossowski, Stefan)(DE)(PD).adf / Berserker / berserker.s < prev    next >
Text File  |  1990-07-19  |  27KB  |  1,130 lines
  1. * SOS *  only a message for a tool which rips source after guru/reset!
  2. ****************************************************************************
  3. *
  4. *                         B E R S E R K E R  IV.a
  5. *                         -----------------------
  6. *
  7. *                 © Copyright 1988, 1989, 1990 by Ralf Thanner
  8. *
  9. * This code is entirely written in assembler for the Kuma Seka assembler
  10. *
  11. *    Executable program and source code are both in the PUBLIC-DOMAIN!
  12. *
  13. *  A small copy fee for Berserker is okay, but anything which looks like
  14. *        commercial redistribution is forbidden (remember that!).
  15. *
  16. **************************************************************************
  17. *
  18. *    REVISION HISTORY:
  19. *    =================
  20. *
  21. *  R    V1.0    - Just a primitive SCA finder and killer.
  22. *
  23. *  R    V1.c    - Added Byte Bandit & Byte Warrior killer.
  24. *        - Improved SCA & SCA mutants killer routine.
  25. *          -> OBELISK, AEK, LSD, PENTAGON, BAMIGA SECTOR ONE,
  26. *             WARHWAK, MICROMASTER & NORTHSTAR...
  27. *
  28. *  R    V2.b    - Now also finds the Exterminator (LAMER).
  29. *
  30. *  R    V2.d    - Now finds the first link virus (IRQ TEAM 41).
  31. *
  32. *    V2.e    - Added alert box. Idea by Olaf Barthel.
  33. *        - Some cleanups and bug-fixes done.
  34. *
  35. *  R    V2.e+    - Doesn't refuse to work with Kick 1.3 any more.
  36. *        - Added custom bootblock writer.
  37. *        - Added kill cold-cool vectors;
  38. *          There are just too many SCA clones on the market
  39. *          and it is saver to clear these pointers.
  40. *
  41. *  R    V3.0    - Now also finds the BSG 9 link virus.
  42. *        - Second (and final?) code cleanup for public
  43. *          release (YEAH!!!).
  44. *        - Removed the custom bootblock writer, too many guys
  45. *          thought Berserker to be some kind of virus in
  46. *          disguise.
  47. *
  48. *  R    V3.0+    - Extended to find Gaddafi and Disk-Doctor viruses.
  49. *
  50. *    V3.1    - Extended to find the REVENGE BOOTLOADER virus.
  51. *          -> THIS IS A NEW ONE!!!
  52. *        - Bug-fix in EXTERMINATOR routine done.
  53. *          -> should now find ALL lamer versions....
  54. *        - Code cleanup (added some sub-routines).
  55. *
  56. *    V3.2    - Extended to find REVENGE (is an old one, but some
  57. *          nice guys told me, that berserker should also find
  58. *          the old ones....and because BERSERKER crashed when
  59. *          memory was infiltrated by REVENGE )
  60. *
  61. *    V3.2b   - Shortening, speeding up & cleaning the code.
  62. *          ( and berserker still works.... )
  63. *
  64. *  R    V3.39c+ - JOKE....
  65. *
  66. *    V3.5    - Added Xeno 'killer' routine by STEVE TIBBET.
  67. *
  68. *    V4.0    - Added a more userfriendly Cli-Interface and the
  69. *          possibility to start BERSERKER from workbench.
  70. *
  71. *  R    V4.0a    - WHAAA, what a pity: forgot to reply message..
  72. *          Bug now fixed... Thanks to Olaf for this hint.
  73. *        - Shortened and improved code again.
  74. *
  75. *  R = released version
  76. * 
  77. **************************************************************************
  78. *    BECAUSE OF THE LARGE AMOUNT OF TEXTDATA WOULD I SUPPOSE
  79. *    THAT YOU CRUNCH BERSERKER. ( with any hunk packer.. ) 
  80. **************************************************************************
  81. *
  82. *                RALF THANNER
  83. *                   ELLERSTASSE 83
  84. *                 4000 DUESSELDORF 1
  85. *                WEST GERMANY
  86. *
  87. **************************************************************************
  88. *
  89. *   This is the assembly language source code for BERSERKER IV.a
  90. * (Cleaned up on request from Ralf Thanner by Olaf 'Olsen' Barthel)
  91. *
  92. **************************************************************************
  93.  
  94. ;
  95. ;
  96. ;     exec.library
  97. ;
  98.  
  99. forbid=        -132
  100. permit=        -138
  101. freemem=    -210
  102. findname=    -276
  103. findtask=    -294
  104. getmsg=        -372
  105. replymsg=    -378
  106. waitport=    -384
  107. closelib=    -414
  108. openlib=    -552
  109.  
  110. ;
  111. ;    dos.library
  112. ;
  113.  
  114. open=        -30
  115. close=        -36
  116. read=        -42
  117. write=        -48
  118. output=        -60
  119. delay=        -198
  120.  
  121. mode_old=    1005
  122.  
  123. ;
  124. ;    intuition.library
  125. ;
  126.  
  127. dispalert=    -90
  128.  
  129. ;
  130. ;
  131. **********************************************************************
  132.  
  133. powerup:
  134.     movem.l        d0-d7/a0-a6,-(a7)
  135.  
  136.     bset        #1,$bfe001
  137.  
  138.  
  139.     move.l        $04.w,a6
  140.     suba.l        a1,a1
  141.     jsr        findtask(a6)
  142.     move.l        d0,a4
  143.     tst.l        $ac(a4)
  144.     bne.s        cli_call
  145.     lea        $5c(a4),a0
  146.     jsr        waitport(a6)
  147.     lea        $5c(a4),a0
  148.     jsr        getmsg(a6)
  149.     move.l        d0,message
  150.  
  151.     movem.l     (a7)+,d0-d7/a0-a6
  152.     bra.L        workbench
  153.  
  154. * CLI-PARAMETER HANDLER        -> same as in MEGUARD III
  155.  
  156. cli_call:
  157.     movem.l     (a7)+,d0-d7/a0-a6
  158.     subq        #1,d0
  159.     beq.s        no_cli_parameter
  160. which_parameter:
  161.     cmp.b        #$20,(a0)+
  162.     bne.s        parameter_found
  163.     dbra        d0,which_parameter
  164.     bra.s        no_cli_parameter
  165. parameter_found:
  166.     move.b        -(a0),d0    
  167.     cmp.b        #'?',d0
  168.     beq.L        instructions
  169. no_cli_parameter:
  170.  
  171.     move.l        $04.w,a6    ; $04 is ExecBase
  172.     jsr        FORBID(a6)    ; forbid all tasks
  173.  
  174.     bsr.L        open_libs
  175.  
  176.     bsr.L        open_output
  177.  
  178.     bsr.s        kill_viruses
  179.  
  180.     move.w        virusflag,d0
  181.     cmp.w        #0,d0        ; No virus found!!!!
  182.     bne.s        exit4        ; Lucky ones...
  183.     move.l        #mes0,d2
  184.     move.l        #mes0length,d3
  185.      bsr.L        writer
  186.     bra.s        exit3
  187.  
  188. exit4:    bsr.L        alert        ; Virus found
  189.  
  190. exit3:    move.l        $04.w,a6
  191.     jsr         PERMIT(a6)    ; Allow other tasks
  192. exit5:    bsr.L        close_libs
  193.     moveq        #00,d0
  194.     rts
  195.  
  196. exit_workbench:
  197.     bsr.L        close_libs
  198.     move.l        $04.w,a6
  199.     jsr        forbid(a6)
  200.     move.l        message,a1
  201.     jsr        replymsg(a6)
  202.     moveq        #00,d0        ; For clear entry into CLI
  203.     rts                ; Back to CLI...
  204.  
  205. ************************* SUB ROUTINES *********************************
  206.  
  207. kill_viruses:
  208.     bsr.L        Xeno        ; XENO - Link
  209.     bsr.L        revenge        ; REVENGE (old one)    
  210.     bsr.L        revenge_boot    ; REVENGE - BOOTLOADER
  211.     bsr.L        gadaffi        ; Gadaffi
  212.     bsr.L        disk_doctor    ; Disk Doctor
  213.     bsr.L        sca        ; Checks for SCA & mutants
  214.     bsr.L        dasa        ; Checks for Byte Warrior
  215.     bsr.L        irq        ; Link
  216.     bsr.L        bsg        ; Link
  217.     bsr.L        exterminator
  218.     bsr.L        bytebandit
  219.     bsr.L        killcold_cool    ; Always clear the cold and
  220.     rts                ; the cool capture
  221.  
  222. workbench:
  223.     bsr.L        open_libs
  224.     bsr.L        open_con
  225.     bsr.s        work
  226.     bsr.L        close_con
  227.     bra.s        exit_workbench
  228. work:
  229.     bsr.L        write_con_txt
  230.     bsr.L        read_con
  231.     moveq        #0,d0
  232.     move.b        input_buffer,d0
  233.     cmp.b        #'?',d0
  234.     beq.s        work03    ; instructions
  235.     cmp.b        #'q',d0
  236.     beq.s        work04        
  237.     cmp.b        #'Q',d0    ; leave
  238.     beq.s        work04
  239.     cmp.b        #'c',d0
  240.     beq.s        work05    ; kill virus        
  241.     cmp.b        #'C',d0
  242.     beq.s        work05
  243.     bra.s        work
  244.  
  245. work03:
  246.     bsr.L        write_con_ins
  247. mouse:
  248.     move.l        #$0a,d1
  249.     jsr        delay(a5)        
  250.     btst        #10,$dff016
  251.     bne.s        mouse
  252.     clr.w        input_buffer
  253.     bra.s        work
  254.  
  255. work04:    rts
  256.  
  257. work05:
  258.     move.l        $04.w,a6
  259.     jsr        forbid(a6)
  260.     bsr.L        kill_viruses
  261.     move.w        virusflag,d0
  262.     cmp.w        #0,d0
  263.     bne.s        work06
  264.     move.l        #mes7,d2
  265.     move.l        #mes7length,d3
  266.      bsr.L        writer
  267.     move.l        $04.w,a6
  268.     jsr         permit(a6)
  269.     move.l        dosbase,a5
  270. work07:
  271.     move.l        #$0a,d1
  272.     jsr        delay(a5)        
  273.     btst        #10,$dff016    ; right MB
  274.     bne.s        work07
  275.     bra.L        work
  276.  
  277. work06:    bsr.L        alert
  278.     clr.w        virusflag
  279.     move.l        $04.w,a6
  280.     jsr         permit(a6)    ; Allow it all
  281.     bra.L        work
  282.  
  283. open_libs:
  284.     move.l        $04.w,a6    ; Open's dos.library
  285.     moveq        #00,d0
  286.     lea.l        Dosname(pc),a1    ; And gets outputhandle
  287.     jsr        openlib(a6)    ; for the messages...
  288.     move.l        d0,dosbase
  289.     move.l        $04.w,a6
  290.     moveq        #0,d0
  291.     lea         Intname(pc),a1
  292.     jsr         openlib(a6)
  293.     move.l         d0,IntBase    ; buffering the intbase
  294.     rts
  295.  
  296. close_libs:
  297.     move.l        $04.w,a6
  298.     move.l      Dosbase,a1
  299.     jsr         closelib(a6)
  300.     move.l         IntBase,a1    ; close intuition
  301.     jsr         closelib(a6)
  302.     rts
  303.  
  304. open_con:
  305.     move.l        Dosbase,a5
  306.     move.l        #con,d1
  307.     move.l        #mode_old,d2
  308.     jsr        open(a5)
  309.     move.l        d0,handle
  310.     rts
  311.  
  312. close_con:
  313.     move.l        Dosbase,a5
  314.     move.l        handle,d1
  315.     jsr        close(a5)
  316.     rts
  317.  
  318. open_output:
  319.     move.l        Dosbase,a5
  320.     jsr        output(a5)
  321.     move.l        d0,handle
  322.     rts
  323.  
  324. write_con_txt:
  325.     move.l        #con_text,d2
  326.     move.l        #cende-con_text,d3
  327.     bsr.s        writer
  328.     rts
  329.  
  330. read_con:
  331.     move.l        Dosbase,a5
  332.     move.l        handle,d1
  333.     clr.w        input_buffer
  334.     move.l        #input_buffer,d2
  335.     move.l        #2,d3
  336.     jsr        read(a5)
  337.     rts
  338.  
  339. write_con_ins:
  340.     move.l        #con_help,d2
  341.     move.l        #con_help_ende-con_help,d3
  342.     bsr.s        writer
  343.     rts
  344.  
  345. writer:    move.l        Dosbase,a5
  346.     move.l        handle,d1
  347.     jsr        write(a5)
  348.     rts
  349.  
  350. writer1:
  351.     move.l        Dosbase,a5
  352.     move.l        handle,d1
  353.     jsr        write(a5)
  354.     move.l        handle,d1
  355.     move.l        #mes,d2
  356.     move.l        #meslength,d3
  357.     jsr        write(a5)
  358.     rts
  359.  
  360. instructions:
  361.     bsr.L        open_libs
  362.     bsr.L        open_output
  363.     move.l        #mes15,d2    ; Prints out the instructions
  364.     move.l        #mes15length,d3
  365.     bsr.L        writer
  366.     jmp        exit5
  367.  
  368. alert:    move.l        Intbase,a6
  369.     lea        alert1(pc),a0
  370.      moveq        #00,d0        ; Recovery Alert
  371.      move.l         #28,d1
  372.      jsr         dispalert(a6)
  373.     rts
  374.  
  375. killcold_cool:
  376.     move.l        $04.w,a6
  377.     moveq        #0,d3
  378.     move.l        d3,46(a6)    ; cool-capture normal
  379.     move.l        d3,42(a6)    ; cold-capture normal
  380.     move.l        d3,50(a6)
  381.     lea        34(a6),a0    ; New execbase checksum
  382.     clr.w        d0
  383.     moveq        #$17,d1
  384. kcc1:    add.w        (a0)+,d0
  385.     dbf        d1,kcc1
  386.     not.w        d0
  387.     move.w        d0,(a0)
  388.     rts
  389.  
  390. tracker:move.l        $04.w,a6
  391.     lea        350(a6),a0
  392.     lea        Trddevice(pc),a1    ; Searches
  393.     jsr        findname(a6)        ; for trackdisk.device
  394.     move.l        d0,a0
  395.     sub.l        #28,a0            ; that's the most used
  396.     rts                    ; pointer in trd.dev...
  397.  
  398. filler:    move.l        a0,a1            ; fills
  399.     add.l        #$400,a1        ; the virus with zeros
  400.     moveq        #0,d0
  401. fill1:    move.l        d0,(a0)+
  402.     cmpa.l        a0,a1
  403.     bge.s        fill1
  404.     rts
  405.  
  406. clear_kicktag:
  407.     move.l      $04.w,a6
  408.     moveq        #0,d0
  409.     move.l        d0,554(a6)    ; Kickchecksum
  410.     move.l        d0,550(a6)    ; Kicktagptr
  411.     move.l        d0,546(a6)    ; Kickmemptr
  412.     rts
  413.  
  414. ******************* V I R U S  K I L L I N G  P A R T ********************
  415.  
  416. * here begins the part taken from VIRUSX4.0 by STEVE TIBBET
  417.  
  418. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  419. ;
  420. ;    Check for and Remove the Xeno Virus
  421. ;
  422. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  423.  
  424. xeno:
  425.     move.l    DOSBase,a0        ; Get addr of Open() Vector
  426.     sub.w    #$1c,a0
  427.     move.l    (a0),a0
  428.  
  429.     move.l    a0,d0            ;: If Bit 0 of the Address is set,
  430.     btst    #0,d0            ;: then it's not really an address
  431.     bne.s    NoVirus_xeno        
  432.     
  433.     cmp.l    #$B47C03EE,(a0)
  434.     bne.s    NoVirus_xeno
  435.     cmp.l    #$67000224,4(a0)
  436.     bne.s    NoVirus_xeno
  437.  
  438.     ;:: If we're here, we're fairly sure A0 is pointing to the
  439.     ;:: base of the Xeno virus (well, not it's base, but the address
  440.     ;:: of the first vector it stole, the Open() one.
  441.     ;:: So we'll nuke it.  8-)
  442.  
  443.     move.w    #$6000,$4(a0)
  444.     move.w    #$603E,$240(a0)
  445.     move.w    #$601E,$29C(a0)
  446.  
  447. * END OF PART
  448.  
  449.     move.w        #$1941,virusflag
  450.     move.l        #mes13,d2
  451.     move.l        #mes13length,d3
  452.      bsr.L        writer
  453. NoVirus_xeno:
  454.     rts
  455.  
  456. ; i hate to do this, but until now i never got a xeno virus and was
  457. ; therefore not able to do my own killer.
  458. ; in addition to that: I HATE THE WAY S.TIBBET KILLS VIRUSES!!!!!!!
  459. ; it is not very intelligent to look for a checksum....
  460.  
  461. revenge:
  462.     move.l        $04.w,a6
  463.     cmp.l        #$7e060,46(a6)
  464.     bne.s        revenge_ende
  465.     move.l        $c0,d0
  466.     cmp.l        #$0c794ef9,$c0
  467.     bne.s        revenge_ende
  468.  
  469.     move.l        $7e068,-454(a6)    ; restoring the old pointers
  470.     move.l        $7e06e,148(a6)     ; by grabbing his saved systemcalls
  471.  
  472.     lea        $7e000,a0    ; the virus
  473.     bsr.L        filler
  474.  
  475.     lea        $c0,a0        ; CLEAR
  476.     moveq        #0,d0        ; his routine
  477.     moveq.l        #$10,d6        ; located at $c0
  478. rev1:
  479.     move.l        d0,(a0)+
  480.     dbf        d6,rev1
  481.  
  482.     bsr.L        killcold_cool    ; out of memory!! HE HE..
  483.  
  484.     move.w        #$1941,virusflag
  485.     move.l        #mes12,d2
  486.     move.l        #mes12length,d3
  487.      bsr.L        writer1
  488. revenge_ende:
  489.     rts
  490.  
  491. *************************************************************************
  492. * REVENGE is a stupid one, it copies a small CONTROLLER part down to
  493. * $c0 and is ALWAYS located at $7e000. (No interest in Fast Mem!!) 
  494. * I only added this one, because it was easy and BERSERKER III crashed
  495. * when REVENGE was in memory. (uses cold cap., 148(a6) & -454(a6) DOIO)
  496. *************************************************************************
  497.  
  498. revenge_boot:    ; seems to be a brand new one...
  499.     bsr.L        tracker
  500.     move.l        a0,revenge1
  501.     move.l        (a0),d4
  502.     swap        d4
  503.     cmp.b        #$fe,d4        ; Is this pointer normal? (V1.2)
  504.     beq.L        revenge_boot_ende
  505.     cmp.b        #$ff,d4        ; Is this pointer normal? (V1.3)
  506.     beq.L        revenge_boot_ende
  507.  
  508.     move.l        $4.w,a6        ; using his own check
  509.     moveq        #0,d0        ; routine... 
  510.     move.w        $94(a6),d0
  511.     and.l        #$f0,d0
  512.     cmp.w        #$f0,d0
  513.     beq.L        revenge_boot_ende    ; not in memory
  514.  
  515.     move.l        (a0),a1
  516.     add.l        #$228,a1
  517.     move.l        (a1),revenge_track    ; -28(trackdisk.device)
  518.     add.l        #$4,a1
  519.     move.l        (a1),revenge_rast    ; 148(a6)
  520.     add.l        #$4,a1
  521.     move.l        (a1),revenge_alloc    ; the part he spreads
  522.     sub.l        #$3c4,a1
  523.     move.l        a1,revenge_mem        ; his own start
  524.  
  525.     move.l        revenge1,a0        ; restoring pointers
  526.     move.l        revenge_track,(a0)
  527.  
  528.     move.l        revenge_rast,$94(a6)        
  529.  
  530.     bsr.L        clear_kicktag
  531.  
  532.     move.l        revenge_mem,a0
  533.     bsr.L        filler
  534.  
  535.     move.l        revenge_alloc,a0
  536.     bsr.L        filler
  537.  
  538.     move.l        revenge_alloc,a1    ; he allocatesw memory..
  539.     move.l        #$400,d0        ; ani i give it back...
  540.     jsr        freemem(a6)
  541.  
  542.     move.w        #$1941,virusflag
  543.     move.l        #mes11,d2
  544.     move.l        #mes11length,d3
  545.      bsr.L        writer1
  546. revenge_boot_ende:
  547.     rts
  548.  
  549. *************************************************************************
  550. *
  551. * seems to be a new one -> contains ASCII Text 'REVENGE BOOTLOADER' 
  552. *
  553. *************************************************************************
  554.  
  555. disk_doctor:
  556.     move.l        $04.w,a6    ; Disk-Doc uses cold & cool capture
  557.     move.l        46(a6),d0
  558.     cmp.l        #0,d0        ; No other virus uses both
  559.     beq.L        dd0        ; pointers... [ hope so !!! ]
  560.     move.l        42(a6),d0
  561.     cmp.l        #0,d0
  562.     beq.L        dd0
  563.  
  564.     move.l        42(a6),diskdoc    ; I had to add this very
  565.     move.l        diskdoc,a0    ; complicated routine because
  566.     add.l        #$c4,a0        ; Disk-Doc uses or changes:
  567.     move.l        a0,a1        ; - cool capt.
  568.     addq.l        #4,a1        ; - cold capt.
  569.     move.w        #$4e75,(a1)    ; - DoIO
  570.     jsr        (a0)        ; - 148(a6) [what's that?]
  571.     move.l        a2,diskdoc1    ; - The task of clipboard.device
  572.     addq.l        #6,a2
  573.     move.l        a2,a3        ; This routine gets the adress of
  574.     addq.l        #4,a2        ; its task routine and cuts it off
  575.     move.w        #$4e75,(a2)
  576.     jsr        (a3)
  577.     move.l        a0,diskdoc2
  578.     bsr.L        killcold_cool
  579.     move.l        $04.w,a6
  580.     move.l        #$fc06dc,-$1c6(A6); Only Kick 1.2 values, on 1.3
  581.     move.l        #$fc12fc,148(a6)  ; Disk-Doc shouldn't work...
  582.  
  583.     move.l        diskdoc,a0
  584.     move.l        a0,a1
  585.     add.l        #$1a0,a1
  586.     moveq        #0,d0
  587. dd2:    move.l        d0,(a0)+
  588.     cmpa.l        a0,a1
  589.     bge.s        dd2
  590.     move.l        diskdoc1,a2
  591.     move.w        #$4e75,(a2)
  592.     move.l        diskdoc2,a2
  593.     move.w        #$4e75,(a2)
  594.  
  595.     move.w        #$1941,virusflag
  596.     move.l        #mes6,d2
  597.     move.l        #mes6length,d3
  598.      bsr.L        writer1
  599. dd0:    rts
  600.  
  601. ***********************************************************************
  602. *
  603. *    DISK-DOCTOR
  604. *
  605. *    - After each reset Disk Doctor allocates more memory
  606. *    - This was in my opinion the best one, although it could be
  607. *      better: - it uses DoIO pointer from Kick 1.2 (crash on 1.3)
  608. *          - you can read text in the boot-block
  609. *    - it uses the clipboard task for its dirty work
  610. *    - it uses cold & cool capture to stay in memory
  611. *
  612. *    For such kind of virus Guardian or VirusX are the best killers!!
  613. *    ( Find them in the boot and fight them when they are harmless! )
  614. *    Same with TIMEBOMB, Berserker can't fight this one........
  615. ************************************************************************
  616.  
  617. gadaffi:
  618.     move.l        $04.w,a6    ; Gadaffi uses cool capture
  619.     cmp.l        #0,46(a6)    ; for its dirty work...
  620.     beq.s        gad0        ; no cool capture set
  621.  
  622.     cmp.l        #$47414441,$7fb40; Gadaffi
  623.     bne.s        gad0        ; is ALWAYS to be found at $7fb00
  624.  
  625.     move.l        -$1c6(a6),d5    ; $4b0 with 512 kb
  626.     swap        d5
  627.     cmp.w        #$fc,d5        ; $fc06dc (1.2)  $fc0718 (1.3)
  628.     beq.s        gad0
  629.  
  630.     move.l        46(a6),gadaf
  631.     bsr.L        killcold_cool    ; Clear its cool pointer
  632.     move.l        $04.w,a6
  633.     move.l        #$fc06dc,-$1c6(A6)
  634.  
  635.     bsr.L        clear_kicktag
  636.  
  637.     move.l        gadaf,a0
  638.     sub.l        #$dc,a0
  639.     bsr.L        filler
  640.     move.w        #$1941,virusflag
  641.     move.l        #mes4,d2
  642.     move.l        #mes4length,d3
  643.      bsr.L        writer1
  644. gad0:    rts
  645.  
  646. ********************************************************************
  647. *
  648. *    GADAFFI is a mutant version of Byte Warrior
  649. *
  650. *    - It changes cool capture, kicktag. and DoIO
  651. *    - It is much more stupid than Byte Warrior:
  652. *     -> you can read it in the boot...
  653. *     -> normally it crashes with Kick 1.3 because
  654. *        he uses the DoIO vector of 1.2 itself
  655. *    - After 12 resets it tries to kill your drive, or
  656. *      was it playing a drive music ?? (I don't see any difference!)
  657. *
  658. ********************************************************************
  659.  
  660. bsg:
  661.     move.l        $04.w,a6
  662.     move.l        546(a6),d0    ; BSG 9 is a resident module
  663.     adda.l        550(a6),d0    ; It is still in memory after
  664.     adda.l        554(a6),d0    ; a reset
  665.     cmp.l        #0,d0
  666.     beq.s        bsgende
  667.     move.l        550(a6),a0    ; Searching from A0
  668.     move.l        a0,a1
  669.     add.l        #$1000,a1    ; Searching to A1
  670.     move.l        #$00005454,d0    ; Searching for 'TT'
  671.     moveq        #0,d1
  672. bsg0:
  673.     move.w        (a0)+,d1
  674.     cmp.w        d1,d0
  675.     beq.s        bsg1
  676.     cmpa.l        a0,a1
  677.     bge.s        bsg0
  678.     rts                ; Nothing found !
  679.                     ; It is not always a virus which
  680.                     ; uses these pointers. It could
  681. bsg1:                    ; also be your ramdrive....
  682.     move.w        #$5631,d0
  683.     move.w        (a0),d1
  684.     cmp.w        d1,d0
  685.     bne.s        bsg0
  686.     moveq        #0,d0        ; Kills it from beginning
  687.     move.l        a0,a1        ; to 'TTV1' <- its end marker
  688.     move.l        550(a6),a0
  689. bsg2:
  690.     move.l        d0,(a0)+
  691.     cmpa.l        a0,a1
  692.     bne.s        bsg2
  693.  
  694.     bsr.L        clear_kicktag
  695.  
  696.     move.w        #$1941,virusflag
  697.     move.l        #mes2,d2
  698.     move.l        #mes2length,d3
  699.      bsr.L        writer
  700. bsgende:
  701.     rts
  702.  
  703. ********************************************************************
  704. *
  705. *    BSG 9 is an intelligent version of a link virus
  706. *
  707. *    - It always modifies the FIRST file of the startup-
  708. *      sequence
  709. *    - The file now always is about 2608 bytes long
  710. *    - The old file in in the devs dir with
  711. *      spaces instead of a name now
  712. *    - After the fourth or fifth reset it turns the
  713. *      screen black and prints out its stupid message.
  714. *
  715. *********************************************************************
  716.  
  717. irq:    ; changes oldopen
  718.     move.l        $04.w,a6
  719.     move.l        -$196(a6),d4
  720.     swap        d4
  721.     cmp.b        #$fc,d4    ; V1.2 00fc1430  V1.3 00fc146c
  722.     beq.s        irq5
  723.     move.w        #$1942,virusflag
  724.     move.l        -$196(a6),a4
  725.     add.w        #8,a4
  726.     move.l        #$4e714e71,(a4)    ; Castrate virus
  727.     move.l        $04.w,a5
  728.     sub.l        #$196,a5    ; In this part the old
  729.     move.l        (a5),a4        ; oldopenlib call
  730.     add.l        #18,a4        ; is restored...
  731.     move.l        (a4),(a5)
  732.     move.l        #mes3,d2
  733.     move.l        #mes3length,d3
  734.     bsr.L        writer
  735. irq5:    rts
  736.  
  737. **************************************************************
  738. *
  739. *    The IRQ Team Virus was the first link virus
  740. *    on AMIGA...
  741. *
  742. *    It uses oldopenlibrary for its dirty work.
  743. *    In order to work properly with all Kickstart
  744. *    versions the IRQ-virus saves the replaced
  745. *    sytemcall in memory.
  746. *    To let my Berserker work with all kick versions
  747. *    I just grab his saved sytemcall in order to
  748. *    throw him out properly...
  749. *
  750. **************************************************************
  751.  
  752. exterminator:    ; in trddevice, doio & kicktag... ($4678, $414, $898)
  753.     bsr.L        tracker
  754.     move.l        a0,exter
  755.     move.l        (a0),d4
  756.     swap        d4
  757.     cmp.b        #$fe,d4        ; Is the pointer normal (V1.2)
  758.     beq.L        exe4
  759.     cmp.b        #$ff,d4
  760.     beq.L        exe4        ; Is the pointer normal (V1.3)
  761.  
  762.     move.l        a6,a5
  763.     sub.w        #$262,a5    ; In A5 now Exterminator's address..
  764.     move.l        a5,exter1
  765.     move.l        (a5),d4
  766.     swap        d4
  767.     cmp.b        #$fc,d4        ; Is it the normal system call?
  768.     beq.s        exe4
  769.  
  770.     move.l        exter1,a5
  771.     move.l        (a5),a0
  772.     sub.l        #$14e,a0
  773.     move.l        a0,a1
  774.     add.l        #$400,a1
  775.     moveq        #0,d1
  776.     moveq        #0,d0
  777. exe7:
  778.     move.w        #$4c41,d0    ; We are looking for 'LAMER'
  779.     move.w        (a0)+,d1
  780.     cmp.w        d1,d0
  781.     beq.s        exe2
  782.     cmpa.l        a0,a1
  783.     bge.s        exe7
  784.     rts
  785. exe2:
  786.     move.w        #$4d45,d0
  787.     move.w        (a0),d1
  788.     cmp.w        d1,d0
  789.     bne.s        exe7
  790.     add.l        #28,a0        ; Here exteminator saves his
  791.     move.l        (a0)+,a1    ; changed system calls
  792.     move.l        (a0)+,a2
  793.  
  794.     move.w        #$1941,virusflag
  795.  
  796.     bsr.L        clear_kicktag
  797.  
  798.     move.l        exter1,a0    ; Correct both pointers
  799.     move.l        a1,(a0)
  800.     move.l        exter,a0
  801.     move.l        a2,(a0)
  802.     move.l        exter1,a5    ; Crucify it
  803.     move.l        (a5),a0
  804.     sub.l        #$14e,a0
  805.     bsr.L        filler
  806.     move.l        #mes9,d2
  807.     move.l        #mes9length,d3
  808.     bsr.L        writer1
  809. exe4:    rts
  810.  
  811. ***********************************************************************
  812.  
  813. sca:
  814.     move.l        $04.w,a6
  815.     move.l        46(a6),d2    ; Cold-capture
  816.     cmp.l        #0,d2
  817.     bne.s        sca1
  818.     rts
  819. sca1:
  820.     move.w        #$1941,virusflag
  821.     move.l        46(a6),a0
  822.     move.l        a0,a1
  823.     sub.l        #$3e,a0        ; We are now searching
  824.     add.l        #$400,a1    ; for jsr -456(a6) [DoIO]
  825.     moveq        #0,d1        ; if cold capture is set
  826.     moveq        #0,d0        ; and in the routine is
  827. sca2:                    ; a DoIO it is 100% a
  828.     move.w        #$4eae,d0    ; virus ( mostly mutants)
  829.     move.w        (a0)+,d1
  830.     cmp.w        d1,d0
  831.     beq.s        sca3
  832.     cmpa.l        a0,a1
  833.     bge.s        sca2
  834.     rts                ; Nothing found
  835. sca3:
  836.     move.w        #$fe38,d0
  837.     move.w        (a0),d1
  838.     cmp.w        d1,d0
  839.     bne.s        sca2
  840.     move.l        $7eff0,d2    ; Here is the direct test
  841.     cmp.l         #$53434121,d2    ; if it is SCA or AEK or LSD
  842.     beq.s        sca4        ; if it is none of them it is
  843.                     ; another mutant SCA...
  844.     cmp.l        #$4c534421,d2    ; AEK
  845.     beq.s        scamutants
  846.     cmp.l        #$41454b21,d2    ; LSD
  847.     beq.s        scamutants
  848.     bne.s        scamutants
  849. sca4:
  850.     move.l        #mes5,d2    ; SCA
  851.     move.l        #mes5length,d3
  852.      bsr.L        writer1
  853.     bra.s        scakill
  854. scamutants:
  855.     move.l        #mes8,d2    ; Mutant
  856.     move.l        #mes8length,d3
  857.      bsr.L        writer1
  858. scakill:
  859.     move.l        46(a6),a0
  860.     sub.l        #$3e,a0
  861.     bsr.L        filler
  862.     bsr.L        killcold_cool    ; Repairs both vectors
  863.     rts
  864.  
  865. ************************************************************************
  866.  
  867. dasa:
  868.     move.l        $04.w,a6
  869.     move.l        -$1c6(a6),d5    ; $4b0 with 512 kb
  870.     swap        d5
  871.     cmp.w        #$fc,d5        ; $fc06dc (1.2)  $fc0718 (1.3)
  872.     bne.s        dasa0
  873.     move.l        $7f804,d5    ; Dasa is ALWAYS at $7f800
  874.     cmp.l        #$64116dec,d5    ; no need to restore doio
  875.     beq.s        dasa1        ; pointer (not changed)
  876.     rts
  877. dasa0:
  878.     move.l        #$00fc06dc,-$1c6(a6)    ; Remove its pointer
  879. dasa1:    move.l        -$1c6(a6),a3
  880.     sub.l        #$16e,a3    ; Its beginning
  881.  
  882.     bsr.L        clear_kicktag
  883.  
  884.     move.l        #$4ff,d1    ; Delete virus
  885. dasa2:    move.b        d0,(a3)+
  886.     dbf        d1,dasa2
  887.     move.w        #$1941,virusflag
  888.     move.l        #mes1,d2
  889.     move.l        #mes1length,d3
  890.     bsr.L        writer1
  891.     rts
  892.  
  893. ****************************************************************
  894. *
  895. *    DASA is the Byte Warrior
  896. *
  897. *    DASA is always located at $7f800 and since
  898. *    it uses a direct jump for DoIO of kick V1.2
  899. *    ( jmp $fc06dc ) for his own copy-routines it
  900. *    crashes on kick v1.3.
  901. *    Therefore I have added this two way search, because
  902. *    when it's kick 1.3 DASA can't work but is still in
  903. *    memory and I don't like a virus in memory...
  904. *
  905. *        ONLY A DEAD VIRUS IS A GOOD VIRUS!!!!
  906. *
  907. ***************************************************************
  908.  
  909. bytebandit:            ; Searches for byte bandit
  910.  
  911.     bsr.L        tracker
  912.     move.l        a0,bb1
  913.     cmp.l        #$00f00000,a0
  914.     ble.s        bytebandit1    ; OK! DoIO is changed
  915.     rts
  916.  
  917. bytebandit1:
  918.     move.l        148(a6),a0    ; Now second test if it
  919.     cmp.l        #$00f00000,a0    ; is really byte bandit
  920.     ble.s        bytebandit2    ; LAMER also changes DoIO!
  921.     rts
  922.  
  923. bytebandit2:    ; it is byte bandit!!
  924.     move.l        a0,a4
  925.     add.l        #$10c,a0    ; Here the pointers are
  926.     move.l        (a0)+,a1    ; saved...
  927.     move.l        (a0),a2
  928.     move.l        bb1,a0
  929.     move.l        a1,(a0)        ; Restoring both
  930.     move.l        a2,148(a6)    ; pointers...
  931.  
  932.     bsr.L        clear_kicktag
  933.  
  934.     sub.l        #$2ca,a4    ; Its beginning
  935.     move.l        a4,a0
  936.     bsr.L        filler
  937.  
  938.     move.w        #$1941,virusflag
  939.     move.l        #mes10,d2
  940.     move.l        #mes10length,d3
  941.     bsr.L        writer1
  942.     rts
  943.  
  944. ***************** M E S S A G E S  AND  D A T A S ********************
  945. even
  946. mes:    dc.b $0a,'Virus killed, check your disks....'
  947.     dc.b $0a,$0a             
  948. mesend:
  949. meslength = mesend-mes
  950. even
  951. mes0:    dc.b $0a,$9b,'7;32;41m'
  952.     dc.b $1b,'[1m'
  953.     dc.b '   BERSERKER found ** NO VIRUS ** in memory !!!  '   
  954.     dc.b $1b,'[0m'
  955.     dc.b $9b,'0;31;40m'
  956.     dc.b $0a,$0a
  957. mes0end:
  958. mes0length = mes0end-mes0
  959. even
  960. mes1:    dc.b $0a,' DANGER!! BYTE - WARRIOR (DASA) VIRUS found'
  961. mes1end:
  962. mes1length = mes1end-mes1
  963. even
  964. mes2:    dc.b $0a,' DANGER!!  BSG 9 LINK -  VIRUS killed!!!'                
  965.     dc.b $0a,'Check first prog. in startup seq. or look into devs.'
  966.     dc.b $0a,$0a
  967. mes2end:
  968. mes2length = mes2end-mes2
  969. even
  970. mes3:    dc.b $0a,' DANGER!!  IRQ LINK - VIRUS killed!!!'                
  971.     dc.b $0a,'Check 2nd prog. in startup seq. or cli-command DIR.'
  972.     dc.b $0a,$0a
  973. mes3end:
  974. mes3length = mes3end-mes3
  975. even
  976. mes4:    dc.b $0a,' DANGER!!  GADAFFI - VIRUS found!!!'                
  977. mes4end:
  978. mes4length = mes4end-mes4
  979. even
  980. mes5:    dc.b $0a,' DANGER!!  SCA - VIRUS found!!!'                
  981. mes5end:
  982. mes5length = mes5end-mes5
  983. even
  984. mes6:    dc.b $0a,' DANGER!!  Disk-Doctor VIRUS found!!!'                
  985. mes6end:
  986. mes6length = mes6end-mes6
  987. even
  988. mes7:    dc.b $0a,' '
  989.     dc.b $0a,$0a,$0a
  990.     dc.b $0a,$9b,'7;32;41m'
  991.     dc.b '        ** NO KNOWN VIRUS ** found        '
  992.     dc.b $9b,'0;31;40m'
  993.     dc.b $0a,$0a,$0a,$0a
  994.     dc.b $1b,'[1m'
  995.     dc.b '        PRESS RIGHT MOUSE BUTTON...'
  996.     dc.b $1b,'[0m'
  997. mes7end:
  998. mes7length = mes7end-mes7
  999. even
  1000. mes8:    dc.b $0a,' DANGER!!  MUTANT SCA - VIRUS found!!!'                
  1001. mes8end:
  1002. mes8length = mes8end-mes8
  1003. even
  1004. mes9:    dc.b $0a,' DANGER!!  EXTERMINATOR (Lamer!) found!!!'                
  1005. mes9end:
  1006. mes9length = mes9end-mes9
  1007. even
  1008. mes10:    dc.b $0a,' DANGER!!  BYTE - BANDIT VIRUS found!!!'
  1009. mes10end:
  1010. mes10length = mes10end-mes10
  1011. even
  1012. mes11:    dc.b $0a,' DANGER!! REVENGE - BOOTLOADER VIRUS found!'
  1013. mes11end:
  1014. mes11length = mes11end-mes11
  1015. even
  1016. mes12:    dc.b $0a,' DANGER!! REVENGE VIRUS found!'
  1017. mes12end:
  1018. mes12length = mes12end-mes12
  1019. even
  1020. mes13:    dc.b $0a,' DANGER!!  XENO LINK - VIRUS neutralized!!'                
  1021.     dc.b $0a,'Check files on disks and hard-disk with "KV".'
  1022.     dc.b $0a,$0a
  1023. mes13end:
  1024. mes13length = mes13end-mes13
  1025. even
  1026. mes15:
  1027. dc.b $0c,$0a,$1b,'[1m','                      *****  BERSERKER IV.a  *****'
  1028. dc.b $1b,'[0m'
  1029. dc.b    $0a
  1030. dc.b $0a,'       1. This Viruskiller finds and destroys the following:'
  1031. dc.b $0a,'          Byte Bandit,  Byte Warrior (DASA), SCA,  AEK, LSD,'
  1032. dc.b $0a,'          OBELISK, WARHAWK,  PENTAGON, BAMIGA S1, NORTHSTAR,'
  1033. dc.b $0a,'          Exterminator (LAMER) all versions,  GADAFFI Virus,'
  1034. dc.b $0a,'          Disk-Doctor Virus, IRQ-Team 41 Virus (Link Virus),'
  1035. dc.b $0a,'          BSG9 VIRUS (Link Virus), REVENGE BOOTLOADER Virus,'
  1036. dc.b $0a,'          REVENGE Virus & XENO Link Virus.'
  1037. dc.b $0a,'       2. All bootblock  viruses  will be deleted from memory'
  1038. dc.b $0a,'          and all  changed  system pointers will be restored.'
  1039. dc.b $0a,'       3. The  Link Viruses  are only  killed in memory. They'
  1040. dc.b $0a,'          might have infected some prgs. on disk!! Take care!'
  1041. dc.b $0a,'       4. Berserker always corrects cold- and coolcapture....'
  1042. dc.b $0a,'          Berserker works with more memory & all  kickstarts.'
  1043. dc.b $0a,'       5. Hi to  Thorsten, Olaf, Gunnar, Henning and Michael.'
  1044. dc.b $0a,'       6. You  can  also  execute  Berserker  from Workbench.'
  1045. dc.b    $0a
  1046. dc.b $1b,'[1m'
  1047. dc.b $0a,'                                    This program is in the PUBLIC DOMAIN!!!'
  1048. dc.b $1b,'[3m'
  1049. dc.b    $0a
  1050. dc.b $0a,'                               ©Copyright 1988, 1989, 1990 by Ralf Thanner.'
  1051. dc.b $1b,'[0m'
  1052. dc.b $0a
  1053. mes15end:
  1054. mes15length = mes15end-mes15
  1055. even
  1056.  con:
  1057. dc.b'CON:20/11/360/150/            BERSERKER IV.a            ',0
  1058. even
  1059.  con_text:
  1060.     dc.b ' '
  1061.     dc.b $0a,$9b,'7;32;41m'
  1062.     dc.b ' BERSERKER IV  (C) 1990 by RALF THANNER   '   
  1063.     dc.b $9b,'0;31;40m'
  1064.     dc.b $0a,$0a,$0a
  1065.     dc.b '  PLEASE ENTER EITHER:',$0a
  1066.     dc.b '  --------------------'
  1067.     dc.b $0a,$0a
  1068.     dc.b '    "C" or "c" for checking memory.'
  1069.     dc.b $0a,$0a
  1070.     dc.b '    "?" for short instructions.'
  1071.     dc.b $0a,$0a
  1072.     dc.b '    "Q" or "q" for leaving BERSERKER.'
  1073.     dc.b $0a,$0a,$0a
  1074.     dc.b $1b,'[1m'
  1075.     dc.b '  ENTER YOUR CHOICE: '
  1076.     dc.b $1b,'[0m'
  1077.  cende:
  1078. even
  1079.  con_help:
  1080.      dc.b ' '
  1081.     dc.b $0a,'  BERSERKER IV finds the following:'
  1082.     dc.b $0a,'  ---------------------------------'
  1083.     dc.b $0a,'  Byte Bandit,  Byte Warrior,  SCA,  AEK,'
  1084.     dc.b $0a,'  LSD,  OBELISK,  PENTAGON, BS1, WARHAWK,'
  1085.     dc.b $0a,'  NORTHSTAR,  Exterminator  Virus (LAMER),'
  1086.     dc.b $0a,'  GADAFFI,  Disk - Doctor,  IRQ-, Xeno- &'
  1087.     dc.b $0a,'  BSG-9  Link Viruses, REVENGE Virus  and' 
  1088.     dc.b $0a,'  REVENGE BOOTLOADER Virus.'
  1089.     dc.b $0a
  1090.     dc.b $0a,'  All  bootblock  viruses  will be killed'
  1091.     dc.b $0a,'  in memory  and all system pointers will'
  1092.     dc.b $0a,'  be restored. The Link Viruses will ONLY'
  1093.     dc.b $0a,'  be deleted in  memory. They might  have'
  1094.     dc.b $0a,'  infected some prgs on disk....'
  1095.     dc.b $0a,$0a
  1096.     dc.b $1b,'[1m'
  1097.     dc.b '  PRESS RIGHT MOUSE BUTTON'
  1098.     dc.b $1b,'[0m'
  1099.  con_help_ende:
  1100. even
  1101.  revenge1:    dc.l 0
  1102.  revenge_alloc:    dc.l 0
  1103.  revenge_track:    dc.l 0
  1104.  revenge_rast:    dc.l 0
  1105.  revenge_mem:    dc.l 0
  1106.  diskdoc:    dc.l 0
  1107.  diskdoc1:    dc.l 0
  1108.  diskdoc2:    dc.l 0
  1109.  gadaf:        dc.l 0
  1110.  bb1:        dc.l 0
  1111.  exter:        dc.l 0
  1112.  exter1:    dc.l 0
  1113.  dosbase:     dc.l 0 
  1114.  IntBase:    dc.l 0
  1115.  handle:    dc.l 0
  1116.  message:    dc.l 0
  1117.  virusflag:    dc.w 0
  1118.  input_buffer:    blk.b 2,0
  1119. even
  1120.  trddevice:    dc.b    'trackdisk.device',0
  1121. even
  1122.  IntName:     dc.b    'intuition.library',0
  1123. even
  1124.  dosname:    dc.b    'dos.library',0
  1125. even
  1126. alert1:    dc.w     178
  1127.     dc.b     16
  1128.     dc.b     'Berserker found VIRUS in memory!'
  1129. even
  1130.